How to get today’s date in SAS?

To get today’s date in SAS, you can use the today() or date() functions. These functions return the number of days since January 1, 1960.

To get the current date and time in SAS, use the DATETIME() function. When you use this function, SAS returns the number of seconds between January 1, 1960, and the current time. You must apply a DateTime format to make this value easy to interpret.

For more details on SAS date functions, see our guide on Date Functions in SAS – The Definitive Guide.

Today_date = today(); /* days today is since 1/1/1960 */ 
Today_date = Date(); /* days today is since 1/1/1960 */
Today_datetime = datetime(); /* seconds between January 1, 1960, and the current time.*/

Arithmetic also works in these functions.

Yesterday = today() – 1; 
EndDate = StartDate + 14;

Example:

data _null_;    
    today = today();
    put today date9.;
run;

Here are some date formats you can use to display the current date in SAS.

Create a New SAS Variable with Today’s Date

The today() or date() function can be assigned to a variable in a SAS dataset since SAS dates are represented as the number of days from January 1, 1960. So to view it as a date, apply the desired format.

The DateTime function Writes the DateTime values in the form ddmmmyy:hh:mm:ss.ss.

data ex;
    date=today();
    datetime=datetime();
    format date date9. datetime datetime20.;
run;

proc print;

Create a Date and DateTime variable with any date

Data _null_;
Date =put(Input('01SEP2021' , Date9.),date9.);
DateTime=put(Input('01SEP2021:12:30:00' , DateTime18.),datetime20.);
put date= ;
put datetime=;
run;

Output:

Date=01SEP2021 
DateTime=01SEP2021:12:30:00

Macro Equivalent to create a data and DateTime variable with any date

In Macro language, you must use the literal values inside the %Sysevalf function.

While the %Eval function is used for most of the Macro language’s numeric operations, it also performs character comparisons.

Therefore, the Date, DateTime, and Time that follow the quoted Date and Time values for literals are considered to be characters and not part of the Date and Time values.

Using the %sysevalf function

%put Date = %Sysevalf('01JAN2021'd );
%put DateTime = %Sysevalf('01JAN2006:12:30:00'dt);

Output:

Date = 22281
DateTime = 1925112600

Using %SYSFUNC, INPUTN and PUTN

Date and Time literals don’t allow flexibility in reading the Date and Time values of different forms into SAS, and you can’t format these SAS Date and Time values.

While In the Data Step, you can use the Input and Put function, it is not possible in Macro.

The %sysfunc macro function utilises most of the data step functions. However, the Input and Put functions are not among them.

Instead, you have to use the InputN and PutN Data Step functions.

%put Date2 = %Sysfunc(inputn(01JAN2021,Date9.)) ; /*Reading SAS date*/
%put date3 = %Sysfunc(putn(%Sysevalf('01JAN2021'd),Date9.)); /*Formatting SAS date*/
%put date4 = %Sysfunc(putn(%Sysfunc(inputn(01JAN2021,Date9.)),Date9.)); /*Formatting SAS date*/

Output:

Date2 = 22281
date3 = 01JAN2021
date4 = 01JAN2021

Create a Macro Variable with Today’s Date

You can create a user-defined macro variable with today’s date. Use the TODAY() or date function within the %SYSFUNC function.

User-Defined Macro Variables

%let todaysDate = %sysfunc(today(), date9.);
%let datetime = %sysfunc(datetime(), datetime.);
%put &todaysDate;
%put &datetime;

Output:

11SEP2021
11SEP21:08:36:39

Using Call Symput to create a macro variable with today’s date.

Here we are using CALL SYMPUTX() to create a global macro variable with no trailing spaces. You can use the DATE() function today() function to get the date.

data _null_;
call symputx('dt', put(date(), date9.), 'g');
call symputx('dt1', put(datetime(), datetime.), 'g');
run;

%put &dt;
%put &dt1;

Since SAS dates are numbers, you need to convert them to characters. Use the PUT function with the format you’d like the date format to appear.

Output:

 11SEP2021
 11SEP21:08:39:34

Automatic Macro Variables to get today’s date in SAS

Besides user-defined macro variables, SAS also has automatic macro variables containing the current date.  These macro variables always exist and can be used to get the current date.

The SYSDATE and SYSDATE9 variables contain today’s date. 

The SYSDATE9 contains the current date in the DATE9. format and SYSDATE have the DATE7. format.

The SYSTIME automatic, macro variables will have the date and time the SAS session started.

%put sysdate:  &sysdate;   
%put sysdate9: &sysdate9;  
%put sysday:   &sysday;    
%put systime:  &systime;

Output:

sysdate: 11SEP21
sysdate9: 11SEP2021
sysday: Saturday
systime: 02:32

Using Call Symputx

data _null_;
   call symputx('dt',put("&sysdate9"d,date9.));
run;
%put &dt.;

Output:

01SEP2021

Note that these automatic macro variables are strings. Hence, if you want to use them in a calculation, you must place them between double quotes and the character “d”.

Determining the Current Date for a North America/Denver Time Zone

The TIMEZONE system option specifies the user’s local time zone.

For the list of all timezone, refer here.

option timezone='America/Denver';
data _null_;
    d1=today();
    put d1 nldate.;
run;

10 September 2021

Determining the Current Date for an Asia/India Time Zone

Localization is the way data is read on input and how it is formatted and presented on output. This is defined by the setting of the LOCALE system option.

options locale=English_India;
data _null_;
day=today();
put day nldate.;
run;

10 September 2021

NLDATE Converts the SAS date value to the date value of the specified locale by using the date format descriptors.

The below table lists the values for the LOCALE= System Option.